1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
|
/*
* Cast5 Cipher 16-way parallel algorithm (AVX/x86_64)
*
* Copyright (C) 2012 Johannes Goetzfried
* <Johannes.Goetzfried@informatik.stud.uni-erlangen.de>
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
* USA
*
*/
.file "cast5-avx-x86_64-asm_64.S"
.text
.extern cast5_s1
.extern cast5_s2
.extern cast5_s3
.extern cast5_s4
/* structure of crypto context */
#define km 0
#define kr (16*4)
#define rr ((16*4)+16)
/* s-boxes */
#define s1 cast5_s1
#define s2 cast5_s2
#define s3 cast5_s3
#define s4 cast5_s4
/**********************************************************************
16-way AVX cast5
**********************************************************************/
#define CTX %rdi
#define RL1 %xmm0
#define RR1 %xmm1
#define RL2 %xmm2
#define RR2 %xmm3
#define RL3 %xmm4
#define RR3 %xmm5
#define RL4 %xmm6
#define RR4 %xmm7
#define RX %xmm8
#define RKM %xmm9
#define RKRF %xmm10
#define RKRR %xmm11
#define RTMP %xmm12
#define RMASK %xmm13
#define R32 %xmm14
#define RID1 %rax
#define RID1b %al
#define RID2 %rbx
#define RID2b %bl
#define RGI1 %rdx
#define RGI1bl %dl
#define RGI1bh %dh
#define RGI2 %rcx
#define RGI2bl %cl
#define RGI2bh %ch
#define RFS1 %r8
#define RFS1d %r8d
#define RFS2 %r9
#define RFS2d %r9d
#define RFS3 %r10
#define RFS3d %r10d
#define lookup_32bit(src, dst, op1, op2, op3) \
movb src ## bl, RID1b; \
movb src ## bh, RID2b; \
movl s1(, RID1, 4), dst ## d; \
op1 s2(, RID2, 4), dst ## d; \
shrq $16, src; \
movb src ## bl, RID1b; \
movb src ## bh, RID2b; \
op2 s3(, RID1, 4), dst ## d; \
op3 s4(, RID2, 4), dst ## d;
#define F(a, x, op0, op1, op2, op3) \
op0 a, RKM, x; \
vpslld RKRF, x, RTMP; \
vpsrld RKRR, x, x; \
vpor RTMP, x, x; \
\
vpshufb RMASK, x, x; \
vmovq x, RGI1; \
vpsrldq $8, x, x; \
vmovq x, RGI2; \
\
lookup_32bit(RGI1, RFS1, op1, op2, op3); \
shrq $16, RGI1; \
lookup_32bit(RGI1, RFS2, op1, op2, op3); \
shlq $32, RFS2; \
orq RFS1, RFS2; \
\
lookup_32bit(RGI2, RFS1, op1, op2, op3); \
shrq $16, RGI2; \
lookup_32bit(RGI2, RFS3, op1, op2, op3); \
shlq $32, RFS3; \
orq RFS1, RFS3; \
\
vmovq RFS2, x; \
vpinsrq $1, RFS3, x, x;
#define F1(b, x) F(b, x, vpaddd, xorl, subl, addl)
#define F2(b, x) F(b, x, vpxor, subl, addl, xorl)
#define F3(b, x) F(b, x, vpsubd, addl, xorl, subl)
#define subround(a, b, x, n, f) \
F ## f(b, x); \
vpxor a, x, a;
#define round(l, r, n, f) \
vbroadcastss (km+(4*n))(CTX), RKM; \
vpinsrb $0, (kr+n)(CTX), RKRF, RKRF; \
vpsubq RKRF, R32, RKRR; \
subround(l ## 1, r ## 1, RX, n, f); \
subround(l ## 2, r ## 2, RX, n, f); \
subround(l ## 3, r ## 3, RX, n, f); \
subround(l ## 4, r ## 4, RX, n, f);
#define transpose_2x4(x0, x1, t0, t1) \
vpunpckldq x1, x0, t0; \
vpunpckhdq x1, x0, t1; \
\
vpunpcklqdq t1, t0, x0; \
vpunpckhqdq t1, t0, x1;
#define inpack_blocks(in, x0, x1, t0, t1) \
vmovdqu (0*4*4)(in), x0; \
vmovdqu (1*4*4)(in), x1; \
vpshufb RMASK, x0, x0; \
vpshufb RMASK, x1, x1; \
\
transpose_2x4(x0, x1, t0, t1)
#define outunpack_blocks(out, x0, x1, t0, t1) \
transpose_2x4(x0, x1, t0, t1) \
\
vpshufb RMASK, x0, x0; \
vpshufb RMASK, x1, x1; \
vmovdqu x0, (0*4*4)(out); \
vmovdqu x1, (1*4*4)(out);
#define outunpack_xor_blocks(out, x0, x1, t0, t1) \
transpose_2x4(x0, x1, t0, t1) \
\
vpshufb RMASK, x0, x0; \
vpshufb RMASK, x1, x1; \
vpxor (0*4*4)(out), x0, x0; \
vmovdqu x0, (0*4*4)(out); \
vpxor (1*4*4)(out), x1, x1; \
vmovdqu x1, (1*4*4)(out);
.align 16
.Lbswap_mask:
.byte 3, 2, 1, 0, 7, 6, 5, 4, 11, 10, 9, 8, 15, 14, 13, 12
.L32_mask:
.byte 32, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0 ,0, 0, 0, 0, 0
.align 16
.global __cast5_enc_blk_16way
.type __cast5_enc_blk_16way,@function;
__cast5_enc_blk_16way:
/* input:
* %rdi: ctx, CTX
* %rsi: dst
* %rdx: src
* %rcx: bool, if true: xor output
*/
pushq %rbx;
pushq %rcx;
vmovdqu .Lbswap_mask, RMASK;
vmovdqu .L32_mask, R32;
vpxor RKRF, RKRF, RKRF;
inpack_blocks(%rdx, RL1, RR1, RTMP, RX);
leaq (2*4*4)(%rdx), %rax;
inpack_blocks(%rax, RL2, RR2, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
inpack_blocks(%rax, RL3, RR3, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
inpack_blocks(%rax, RL4, RR4, RTMP, RX);
xorq RID1, RID1;
xorq RID2, RID2;
round(RL, RR, 0, 1);
round(RR, RL, 1, 2);
round(RL, RR, 2, 3);
round(RR, RL, 3, 1);
round(RL, RR, 4, 2);
round(RR, RL, 5, 3);
round(RL, RR, 6, 1);
round(RR, RL, 7, 2);
round(RL, RR, 8, 3);
round(RR, RL, 9, 1);
round(RL, RR, 10, 2);
round(RR, RL, 11, 3);
movb rr(CTX), %al;
testb %al, %al;
jnz __skip_enc;
round(RL, RR, 12, 1);
round(RR, RL, 13, 2);
round(RL, RR, 14, 3);
round(RR, RL, 15, 1);
__skip_enc:
popq %rcx;
popq %rbx;
testb %cl, %cl;
jnz __enc_xor16;
outunpack_blocks(%rsi, RR1, RL1, RTMP, RX);
leaq (2*4*4)(%rsi), %rax;
outunpack_blocks(%rax, RR2, RL2, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
outunpack_blocks(%rax, RR3, RL3, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
outunpack_blocks(%rax, RR4, RL4, RTMP, RX);
ret;
__enc_xor16:
outunpack_xor_blocks(%rsi, RR1, RL1, RTMP, RX);
leaq (2*4*4)(%rsi), %rax;
outunpack_xor_blocks(%rax, RR2, RL2, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
outunpack_xor_blocks(%rax, RR3, RL3, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
outunpack_xor_blocks(%rax, RR4, RL4, RTMP, RX);
ret;
.align 16
.global cast5_dec_blk_16way
.type cast5_dec_blk_16way,@function;
cast5_dec_blk_16way:
/* input:
* %rdi: ctx, CTX
* %rsi: dst
* %rdx: src
*/
pushq %rbx;
vmovdqu .Lbswap_mask, RMASK;
vmovdqu .L32_mask, R32;
vpxor RKRF, RKRF, RKRF;
inpack_blocks(%rdx, RL1, RR1, RTMP, RX);
leaq (2*4*4)(%rdx), %rax;
inpack_blocks(%rax, RL2, RR2, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
inpack_blocks(%rax, RL3, RR3, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
inpack_blocks(%rax, RL4, RR4, RTMP, RX);
xorq RID1, RID1;
xorq RID2, RID2;
movb rr(CTX), %al;
testb %al, %al;
jnz __skip_dec;
round(RL, RR, 15, 1);
round(RR, RL, 14, 3);
round(RL, RR, 13, 2);
round(RR, RL, 12, 1);
__skip_dec:
round(RL, RR, 11, 3);
round(RR, RL, 10, 2);
round(RL, RR, 9, 1);
round(RR, RL, 8, 3);
round(RL, RR, 7, 2);
round(RR, RL, 6, 1);
round(RL, RR, 5, 3);
round(RR, RL, 4, 2);
round(RL, RR, 3, 1);
round(RR, RL, 2, 3);
round(RL, RR, 1, 2);
round(RR, RL, 0, 1);
popq %rbx;
outunpack_blocks(%rsi, RR1, RL1, RTMP, RX);
leaq (2*4*4)(%rsi), %rax;
outunpack_blocks(%rax, RR2, RL2, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
outunpack_blocks(%rax, RR3, RL3, RTMP, RX);
leaq (2*4*4)(%rax), %rax;
outunpack_blocks(%rax, RR4, RL4, RTMP, RX);
ret;
|
