summaryrefslogtreecommitdiffstats
path: root/src/input-device/input-device.vala
blob: 1c558d07c3b0bbc53755714809c126f761f78960 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
/* Copyright 2015, Sebastian Reichel <sre@ring0.de>
 * Copyright 2017-2018, Johannes Rudolph <johannes.rudolph@gmx.com>
 *
 * Permission to use, copy, modify, and/or distribute this software for any
 * purpose with or without fee is hereby granted, provided that the above
 * copyright notice and this permission notice appear in all copies.
 *
 * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
 * WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
 * MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
 * ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
 * WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
 * ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
 * OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
 */

[DBus (name = "io.mainframe.shopsystem.InputDevice")]
public class Device {
	private IOChannel io_read;
	private string buffer;
	private bool shift;

	public signal void received_barcode(string barcode);

	public Device(string device) {
		if (device == "ignore") {
			stdout.printf("Ignoring InputDevice!\n");
			return;
		}
		try {
			io_read = new IOChannel.file(device, "r");
			buffer = "";
			shift = false;

			int fd = io_read.unix_get_fd();
			int flags = Posix.fcntl(fd, Posix.F_GETFL, 0);
			Posix.fcntl(fd, Posix.F_SETFL, flags | Posix.O_NONBLOCK);

			if(!(io_read.add_watch(IOCondition.IN | IOCondition.HUP, device_read) != 0)) {
				error("Could not bind IOChannel");
			}
		} catch(FileError e) {
			error("FileError: %s", e.message);
		}
	}

	private char linux_event_lookup(uint16 code) {
		int c = code;

		switch(c) {
			case Linux.Input.KEY_0:
				return '0';
			case Linux.Input.KEY_1:
				return '1';
			case Linux.Input.KEY_2:
				return '2';
			case Linux.Input.KEY_3:
				return '3';
			case Linux.Input.KEY_4:
				return '4';
			case Linux.Input.KEY_5:
				return '5';
			case Linux.Input.KEY_6:
				return '6';
			case Linux.Input.KEY_7:
				return '7';
			case Linux.Input.KEY_8:
				return '8';
			case Linux.Input.KEY_9:
				return '9';
			case Linux.Input.KEY_A:
				return 'a';
			case Linux.Input.KEY_B:
				return 'b';
			case Linux.Input.KEY_C:
				return 'c';
			case Linux.Input.KEY_D:
				return 'd';
			case Linux.Input.KEY_E:
				return 'e';
			case Linux.Input.KEY_F:
				return 'f';
			case Linux.Input.KEY_G:
				return 'g';
			case Linux.Input.KEY_H:
				return 'h';
			case Linux.Input.KEY_I:
				return 'i';
			case Linux.Input.KEY_J:
				return 'j';
			case Linux.Input.KEY_K:
				return 'k';
			case Linux.Input.KEY_L:
				return 'l';
			case Linux.Input.KEY_M:
				return 'm';
			case Linux.Input.KEY_N:
				return 'n';
			case Linux.Input.KEY_O:
				return 'o';
			case Linux.Input.KEY_P:
				return 'p';
			case Linux.Input.KEY_Q:
				return 'q';
			case Linux.Input.KEY_R:
				return 'r';
			case Linux.Input.KEY_S:
				return 's';
			case Linux.Input.KEY_T:
				return 't';
			case Linux.Input.KEY_U:
				return 'u';
			case Linux.Input.KEY_V:
				return 'v';
			case Linux.Input.KEY_W:
				return 'w';
			case Linux.Input.KEY_X:
				return 'x';
			case Linux.Input.KEY_Y:
				return 'y';
			case Linux.Input.KEY_Z:
				return 'z';
			case Linux.Input.KEY_SPACE:
				return ' ';
			case Linux.Input.KEY_DOT:
				return '.';
			case Linux.Input.KEY_MINUS:
				return '-';
			case Linux.Input.KEY_SLASH:
				return '/';
			case Linux.Input.KEY_ENTER:
				return '\n';
			default:
				return '\0';
		}
	}

	private char linux_event_lookup_shift(uint16 code) {
		int c = code;

		switch(c) {
			case Linux.Input.KEY_EQUAL:
				return '+';
			case Linux.Input.KEY_4:
				return '$';
			case Linux.Input.KEY_5:
				return '%';
			case Linux.Input.KEY_A:
				return 'A';
			case Linux.Input.KEY_B:
				return 'B';
			case Linux.Input.KEY_C:
				return 'C';
			case Linux.Input.KEY_D:
				return 'D';
			case Linux.Input.KEY_E:
				return 'E';
			case Linux.Input.KEY_F:
				return 'F';
			case Linux.Input.KEY_G:
				return 'G';
			case Linux.Input.KEY_H:
				return 'H';
			case Linux.Input.KEY_I:
				return 'I';
			case Linux.Input.KEY_J:
				return 'J';
			case Linux.Input.KEY_K:
				return 'K';
			case Linux.Input.KEY_L:
				return 'L';
			case Linux.Input.KEY_M:
				return 'M';
			case Linux.Input.KEY_N:
				return 'N';
			case Linux.Input.KEY_O:
				return 'O';
			case Linux.Input.KEY_P:
				return 'P';
			case Linux.Input.KEY_Q:
				return 'Q';
			case Linux.Input.KEY_R:
				return 'R';
			case Linux.Input.KEY_S:
				return 'S';
			case Linux.Input.KEY_T:
				return 'T';
			case Linux.Input.KEY_U:
				return 'U';
			case Linux.Input.KEY_V:
				return 'V';
			case Linux.Input.KEY_W:
				return 'W';
			case Linux.Input.KEY_X:
				return 'X';
			case Linux.Input.KEY_Y:
				return 'Y';
			case Linux.Input.KEY_Z:
				return 'Z';
			case Linux.Input.KEY_SPACE:
				return ' ';
			case Linux.Input.KEY_ENTER:
				return '\n';
			default:
				return '\0';

		}
	}

	private bool device_read(IOChannel source, IOCondition cond) {
		Linux.Input.Event ev = {};
		char key = '\0';

		if((cond & IOCondition.HUP) == IOCondition.HUP)
			error("Lost device");

		do {
			int fd = source.unix_get_fd();
			ssize_t s = Posix.read(fd, &ev, sizeof(Linux.Input.Event));

			/* short read */
			if (s != sizeof(Linux.Input.Event)) {
				if(s > 0)
					stdout.printf("short read!\n");
				return true;
			}

			/* only handle key events */
			if (ev.type != Linux.Input.EV_KEY)
				continue;

			if (ev.code == Linux.Input.KEY_LEFTSHIFT) {
				shift = (ev.value == 1);
				continue;
			}

			/* ignore key-release */
			if (ev.value != 1)
				continue;

			/* key event to ascii */
			key = shift ? linux_event_lookup_shift(ev.code) : linux_event_lookup(ev.code);

			/* add buffer */
			if (key != '\n')
				buffer += "%c".printf(key);
		} while(key != '\n');

		stdout.printf("barcode: %s\n", buffer);

		if(buffer.has_prefix("USER ") || buffer.has_prefix("STOCK") || buffer.has_prefix("AMOUNT ")) {
			if(!check_code39_checksum(buffer))
				received_barcode("SCANNER RETURNED INCORRECT DATA");
			else  {/* remove checksum */
				buffer = buffer[0:-1];
				received_barcode(buffer);
			}
		}
		else
			received_barcode(buffer);

		buffer = "";
		return true;
	}

	private bool check_code39_checksum(string data) {
		int result = 0;

		for(int i = 0; i<data.length-1; i++) {
			if(data[i] >= '0' && data[i] <= '9')
				result += data[i] - '0';
			else if(data[i] >= 'A' && data[i] <= 'Z')
				result += data[i] - 'A' + 10;
			else
				switch(data[i]) {
					case '-':
						result += 36; break;
					case '.':
						result += 37; break;
					case ' ':
						result += 38; break;
					case '$':
						result += 39; break;
					case '/':
						result += 40; break;
					case '+':
						result += 41; break;
					case '%':
						result += 42; break;
					default:
						/* invalid character */
						return false;
				}

			result %= 43;
		}

		if(result < 10)
			result = result + '0';
		else if(result < 36)
			result = result - 10 + 'A';
		else
			switch(result) {
				case 36: result = '-'; break;
				case 37: result = '.'; break;
				case 38: result = ' '; break;
				case 39: result = '$'; break;
				case 40: result = '/'; break;
				case 41: result = '+'; break;
				case 42: result = '%'; break;
			}

		return (data[data.length-1] == result);
	}

	/**
	 * @param duration duration of the blink in 0.1 seconds
	 */
	public void blink(uint duration)  throws IOError, DBusError {
		/* not supported */
	}
}